# Wolfden Player_Shop NPC =
#================================================
# 
ASSN_Wolfden_Player_Shop:
  Type: Assignment
  Interact Scripts:
  - 2 Wolfden_Player_Shop
  Actions:
    on assignment:
      - ^trait stockroom
      - ^trait Inventory
      - ^disengage
      - ^trigger name:proximity toggle:true radius:5
      - ^trigger name:chat toggle:true cooldown:0
      - ^flag npc spawnpoint:<npc.location>
      - ^flag npc store_balance:0
      - ^flag npc Is_Player_Owned_NPC_Store:true
      - ^flag npc "store_name:<npc.owner.name>'s Store"
    on enter proximity:
      - lookclose toggle:true
    on exit proximity:
      - ^lookclose toggle:false
      - ^ZAP step:1 script:Wolfden_Player_Shop
      - ^flag player npc_store_purchase_item_selected_quantity:!
      - ^flag player npc_store_purchase_item_selected:!
      - ^QUEUE CLEAR
      - ^Flag Player NPC_INVENTORY_ID:!
    on despawn:
      - ^flag npc npc_inventory:<npc.inventory.list_contents>
    on spawn:
      - ^inventory set destination:<npc.inventory> origin:<npc.flag[npc_inventory]>
Wolfden_Player_Shop:
  Type: Interact
  Requirements:
    Mode: none
  Steps:
      1:
        Chat Trigger:
          1:
            Trigger: /regex:(G|g)reetings|(H|h)i|(H|h)ello/
            Script:
              - ^if <npc.owner.name> contains <player.name> {
                - ^run script:Wolfden_Player_Shop_Owner_Task
                }
                else {
                - ^run script:Wolfden_Player_Shop_Greeting_Task
                }
      2:
        Chat Trigger:
          Offers:
            Trigger: /regex:(A|a)ctions/
            Script:
              - Chat "From here you can<&co>"
              - Chat "<aqua>Deposit<yellow> or <aqua>Withdraw<yellow> Store funds."
              - Chat "Check the store's <aqua>Balance<yellow>."
              - Chat "Check or storck the Store's <aqua>Inventory<yellow>."
              - Chat "Set an item's <aqua>Sell Price<yellow>."
              - Chat "And set the <aqua>Store Name<yellow>."
          Store_Name:
            Trigger: /regex:(S|s)tore (N|n)ame/
            Script:
              - ^Chat "The Store's current name is <npc.flag[Store_Name]>."
              - ^Chat "What would you like to name this store?"
              - ^Zap Store_Name
          1:
            Trigger: /regex:(D|d)eposit/
            Script:
              - ^CHAT "Well <green>Boss<yellow>, How much money do you want to deposit into the store's register?"
              - ^Zap Deposit_Money
          2:
            Trigger: /regex:(W|w)ithdraw/
            Script:
              - ^CHAT "I currently have <green><npc.flag[store_balance]><yellow> Bars, how much would you like to withdraw?"
              - ^Zap Withdraw_Money
          3:
            Trigger: /regex:(B|b)alance/
            Script:
              - ^CHAT "We currently have <green><npc.flag[store_balance]><yellow> Bars in the coffers."
              - ^Chat "Will there be anything else for you today <green>Boss<yellow>?"
              - ^Zap anymore_else
          4:
            Trigger: /regex:(I|i)nventory/
            Script:
              - ^CHAT "Here's what we got in the inventory..."
              - Inventory open d:<npc.inventory> 
              - ^Flag Player NPC_INVENTORY_ID:<npc.id>
          5:
            Trigger: /regex:(S|s)ell (P|p)rice/
            Script:
              - ^if <player.flag[npc_store_item_selected_is_enchanted]> == true {
                - ^flag npc store_item_enchanted_unique_Id:<util.random.duuid><util.date.time.second>
                - ^CHAT "<aqua><player.flag[npc_store_item_name_selected]><yellow> is a rare item, adding unique ID of <aqua><npc.flag[store_item_enchanted_unique_Id]><yellow> for the item so I can track it."
                - ^adjust i@<npc.inventory.slot[<player.flag[npc_store_item_selected_enchanted]>]> "lore:<npc.flag[store_item_enchanted_unique_Id]>" save:Store_Id_Set
                - ^take bydisplay:<player.flag[npc_store_item_name_selected]> from:<npc.inventory>
                - ^give i@<entry[Store_Id_Set].result> to:<npc.inventory>
                - ^flag player npc_store_item_name_selected:<entry[Store_Id_Set].result>
                - ^CHAT "How much would you like to set <aqua><player.flag[npc_store_item_name_display]>'s<yellow> per unit price too?"
                - ^ZAP SELL_PRICE
                }
              - ^if !<player.flag[npc_store_item_selected_is_enchanted]> {
                - ^CHAT "How much would you like to set <aqua><player.flag[npc_store_item_selected]>'s<yellow> per unit price too?"
                - ^Zap Sell_Price
                }
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - ^CHAT "So long <green><player.name><yellow>."
              - ^Zap 1
              - Disengage

#### Sell PRice
      Sell_Price:
        Chat Trigger:
          1:
            Trigger: /regex:\d+(\.\d+)?/
            Script:
              - ^Flag Player Wolfden_Store_Price_amount:<context.keyword>
              - ^if <player.flag[npc_store_item_selected_is_enchanted]> == True {
                - ^CHAT "Do you want to set the selling price for one unit of <aqua><player.flag[npc_store_item_name_display]><yellow> at <aqua><player.flag[wolfden_store_price_amount]><yellow> bars?"
                - ^zap step:Sell_Price_Confirm
                }
              - ^if !<player.flag[npc_store_item_selected_is_enchanted]> {
                - ^CHAT "Do you want to set the selling price for one unit of <aqua><player.flag[npc_store_item_selected]><yellow> at <aqua><player.flag[wolfden_store_price_amount]><yellow> bars?"
                - ^zap step:Sell_Price_Confirm
                }

      Sell_Price_Confirm:
        Chat Trigger:
          1:
            Trigger: /regex:(Y|y)es/
            Script:
              - ^if <player.flag[npc_store_item_selected_is_enchanted]> == True {
                - ^flag npc store_<npc.flag[store_item_enchanted_unique_Id]>:<player.flag[wolfden_store_price_amount]>
                - ^Chat "All right <green>Boss<yellow>, the selling price of <aqua><player.flag[npc_store_item_name_display]><yellow> is now <aqua><player.flag[wolfden_store_price_amount]><yellow>."
                - ^wait 1
                - Chat "Type <aqua>Inventory<yellow> again to keep changing prices."
                - ^zap 2
                }
              - ^if !<player.flag[npc_store_item_selected_is_enchanted]> {
                - flag npc store_<player.flag[npc_store_item_selected]>:<player.flag[wolfden_store_price_amount]>
                - Chat "All right <green>Boss<yellow>, the selling price of <aqua><player.flag[npc_store_item_selected]><yellow> is now <aqua><player.flag[wolfden_store_price_amount]><yellow> per unit."
                - wait 1
                - Chat "Type <aqua>Inventory<yellow> again to keep changing prices."
                - ^zap 2
                }
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "If you say so, Is there anything else for you today?"
              - ^zap Anymore_Else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green>Boss<yellow>!"
              - ^zap 1
              - Disengage

#### DEPOSIT MONEY CONFIRM
      Deposit_Money:
        Chat Trigger:
          1:
            Trigger: /regex:\d+(\.\d+)?/
            Script:
              - ^Flag Player Wolfden_Store_deposit_amount:<context.keyword>
              - ^CHAT "So you want to deposit <aqua><player.flag[Wolfden_Store_deposit_amount]><yellow> bars?"
              - ^IF <player.money> >= <player.flag[Wolfden_Store_deposit_amount]> ^zap step:Deposit_Money_Confirm else run script:Wolfden_Player_Shop_Insufficient_Funds_Task

      Deposit_Money_Confirm:
        Chat Trigger:
          1:
            Trigger: /regex:(Y|y)es/
            Script:
              - CHAT "Excellent please hand over the currency."
              - Take money qty:<player.flag[Wolfden_Store_deposit_amount]>
              - Flag npc store_balance:++:<player.flag[Wolfden_store_deposit_amount]>
              - execute as_server "denizen save"
              - Narrate "You hand over <player.flag[Wolfden_store_deposit_amount]> Bars"
              - Wait 1
              - Chat "All done <green>Boss<yellow>! The store's current coffers are <aqua><npc.flag[store_balance]><yellow> Bars."
              - wait 1
              - Chat "Will there be anything else for you today <green>Boss<yellow>?"
              - ^zap Anymore_Else
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "If you say so, Is there anything else for you today?"
              - ^zap Anymore_Else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green>Boss<yellow>!"
              - ^zap 1
              - Disengage
#### END DEPOT MONEY CONFIRM
#_____________________________
#### Begin Withdraw #####
      Withdraw_Money:
        Chat Trigger:
          1:
            Trigger: /regex:\d+(\.\d+)?/
            Script:
              - ^Flag Player Wolfden_store_withdraw_amount:<context.keyword>
              - ^CHAT "So you want to withdraw <aqua><player.flag[Wolfden_store_withdraw_amount]><yellow> bars?"
              - ^IF <npc.flag[store_balance]> >= <player.flag[Wolfden_store_withdraw_amount]> ^zap step:Withdraw_Money_Confirm else run script:Wolfden_Player_Shop_Shop_Insufficient_Funds_Task
      Withdraw_Money_Confirm:
        Chat Trigger:
          1:
            Trigger: /regex:(Y|y)es/
            Script:
              - CHAT "Alright, Here are your Bars <green>Boss<yellow>!"
              - give money qty:<player.flag[Wolfden_store_withdraw_amount]>
              - Flag npc store_balance:--:<player.flag[Wolfden_store_withdraw_amount]>
              - execute as_server "denizen save"
              - Narrate "The teller hands to you <player.flag[Wolfden_store_withdraw_amount]> Bars"
              - Wait 1
              - Chat "All done. The store's current balance here is now <aqua><npc.flag[store_balance]><yellow> Bars."
              - Wait 1
              - Chat "Will there be anything else for you today <green>Boss<yellow>?"
              - ^Zap anymore_else
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "Alright, Is there anything else for you today?"
              - ^Zap anymore_else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green>Boss!<yellow>"
              - ^zap 1
              - Disengage              
# END WITHDRAWL STEP
#---------------------------------
#------------------------------------
# ANY MORE SHOPPING TO DO YES/NO STEP
      Anymore_Else:
        Chat Trigger:
          1:
            Trigger: /regex:(Y|y)es/
            Script:
              - CHAT "Alright, lets hear what you want."
              - ^if <npc.owner.name> contains <player.name> {
                - ^zap 2
                }
                else {
                - ^zap Non_Owner_Chat
                }
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - ^if <npc.owner.name> contains <player.name> {
                - CHAT "Alright <green>Boss<yellow>; I'll get back to work now."
                - ^Zap 1
                }
                else {
                - CHAT "A Pleasure <green><Player.Name><yellow>. Please come again and do have a good day"
                - DISENGAGE
                - ^zap 1
                }
# Non Owner Chat
      Non_Owner_Chat:
        Chat Trigger:
          Offers:
            Trigger: /regex:(I|i)nventory/
            Script:
              - CHAT "Here's what we have for sale here!"
              - Inventory open d:<npc.inventory>
              - ^Flag Player NPC_INVENTORY_ID:<npc.id>
          1:
            Trigger: /regex:(B|b)uy (I|i)tem/
            Script:
              - ^if <player.flag[npc_store_purchase_item_selected]> == null {
                - Chat "What item..? you need to click on an item in my <aqua>inventory<yellow>!"
                - Queue Clear
                }
              - ^if <player.flag[npc_store_purchase_item_selected_is_enchanted]> == TRUE {
                - Chat "Would you like to buy <player.flag[npc_store_purchase_item_name_selected]><yellow> for <aqua><npc.flag[store_<player.flag[npc_store_purchase_item_ID]>]><yellow> Bars?"
                - ^Zap Buy_Item_Confirm_Purchase
                }
                else if !<player.flag[npc_store_purchase_item_selected_is_enchanted]> {
                - Chat "Would you like to buy some <aqua><player.flag[npc_store_purchase_item_selected]><yellow> for <aqua><npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]><yellow> Bars per unit?"
                - ^Zap Buy_Item_Confirm
                }
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green><player.name><yellow>."
              - ^Zap 1
              - Disengage

      Buy_Item_Confirm:
        Chat Trigger:
          1:
            Trigger: /regex:(Y|y)es/
            Script:
              - CHAT "Alright, and how many units of <aqua><player.flag[npc_store_purchase_item_selected]><yellow> would you like?"
              - ^Zap Buy_Item_Confirm_Quantity
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "Alright, Is there anything else for you today?"
              - ^Zap anymore_else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green><player.name><yellow>."
              - ^zap 1
              - Disengage 

      Buy_Item_Confirm_Quantity:
        Chat Trigger:
          1:
            Trigger: /regex:\d+/
            Script:
              - ^flag player npc_store_purchase_item_selected_quantity:<context.keyword>
              - ^if <player.flag[npc_store_purchase_item_selected_quantity]> <= <npc.inventory.qty[<player.flag[npc_store_purchase_item_selected]>]> {
                - ^CHAT "Would you like to purchase <aqua><player.flag[npc_store_purchase_item_selected_quantity]><yellow> units of <aqua><player.flag[npc_store_purchase_item_selected]><yellow> for <aqua><m.mul[10].round.div[10]:<context.keyword>*<npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]>><yellow>?"
                - ^Zap Buy_Item_Confirm_Purchase
                }
                else {
                - ^run script:Wolfden_Player_Shop_Shop_No_Item
                }
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "Alright, Is there anything else for you today?"
              - ^Zap anymore_else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green><player.name><yellow>."
              - ^zap 1
              - Disengage              

      Buy_Item_Confirm_Purchase:
        Chat Trigger:
          1:
            Trigger: /yes/
            Script:
              - ^if <m.mul[10].round.div[10]:<player.flag[npc_store_purchase_item_selected_quantity]>*<npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]>> > <player.money> {
                - ^run script:Wolfden_Player_Shop_Insufficient_Funds_Task
                - QUEUE CLEAR
                }
              - ^if <player.flag[npc_store_purchase_item_selected_is_enchanted]> == true {
                - ^if <player.money> < <m.mul[10].round.div[10]:<npc.flag[store_<player.flag[npc_store_purchase_item_ID]>]>> {
                  - ^run script:Wolfden_Player_Shop_Insufficient_Funds_Task
                  - QUEUE CLEAR
                  }
                }
              - ^if <player.flag[npc_store_purchase_item_selected_is_enchanted]> == true {
                - Chat "Alright, <green><player.name><yellow> please hand over the cash."
                - Narrate "You hand over <aqua><m.mul[10].round.div[10]:<npc.flag[store_<player.flag[npc_store_purchase_item_ID]>]>> <yellow>Bars"
                - ^take money qty:<m.mul[10].round.div[10]:<npc.flag[store_<player.flag[npc_store_purchase_item_ID]>]>>
                - ^give i@<npc.inventory.slot[<player.flag[npc_store_purchase_item_selected_enchanted]>]> qty:1 to:<player.inventory>
                - ^take i@<npc.inventory.slot[<player.flag[npc_store_purchase_item_selected_enchanted]>]> qty:1 from:<npc.inventory>
                - ^Flag npc store_balance:++:<m.mul[10].round.div[10]:<npc.flag[store_<player.flag[npc_store_purchase_item_ID]>]>>
                - ^Chat "Will there be anything else for you today?"
                - ^Zap step:Anymore_Else script:Wolfden_Player_Shop
                }
              - ^if !<player.flag[npc_store_purchase_item_selected_is_enchanted]> {
                - Chat "Alright, <green><player.name><yellow> please hand over the cash."      
                - Narrate "You hand over <aqua><m.mul[10].round.div[10]:<player.flag[npc_store_purchase_item_selected_quantity]>*<npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]>> <yellow>Bars"
                - ^take money qty:<m.mul[10].round.div[10]:<player.flag[npc_store_purchase_item_selected_quantity]>*<npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]>>
                - ^give i@<player.flag[npc_store_purchase_item_selected]> qty:<player.flag[npc_store_purchase_item_selected_quantity]> to:<player.inventory>
                - ^take i@<player.flag[npc_store_purchase_item_selected]> qty:<player.flag[npc_store_purchase_item_selected_quantity]> from:<npc.inventory>
                - ^Flag npc store_balance:++:<m.mul[10].round.div[10]:<player.flag[npc_store_purchase_item_selected_quantity]>*<npc.flag[store_<player.flag[npc_store_purchase_item_selected]>]>>
                - ^Chat "Will there be anything else for you today?"
                - ^Zap step:Anymore_Else script:Wolfden_Player_Shop
                }

             # - ^inventory move destination:<npc.inventory>/i@<npc.inventory.slot[<player.flag[npc_store_purchase_item_selected_enchanted]>]> origin:<player.inventory>
             #   - ^give i@<player.flag[npc_store_purchase_item_selected]> qty:<player.flag[npc_store_purchase_item_selected_quantity]>
             #- ^inventory remove destination:<npc.inventory>  origin:i@<player.flag[npc_store_purchase_item_selected]>[quantity=<player.flag[npc_store_purchase_item_selected_quantity]>]
             # - ^inventory move destination:<npc.inventory>/i@<player.flag[npc_store_purchase_item_selected]>  origin:<player.inventory>
          2:
            Trigger: /regex:(N|n)o/
            Script:
              - WAIT 1
              - CHAT "Alright, Is there anything else for you today?"
              - ^Zap anymore_else
          Bye:
            Trigger: /regex:(B|b)ye/
            Script:
              - CHAT "So long <green><player.name><yellow>."
              - ^zap 1
              - Disengage              











# Store name
      Store_Name:
        Chat Trigger:
          1:
            Trigger: /regex:\w+/
            Script:
              - ^flag npc store_name:<context.message>
              - ^Narrate "The shop will now be known as <aqua><context.message>"
              - ^Chat "Will there be anything else for you today <green>Boss<yellow>?"
              - ^Zap anymore_else
# INSUFFICIENT FUNDS TASK
Wolfden_Player_Shop_Insufficient_Funds_Task:
    type: task
    Requirements:
    Mode: None
    Script:
      - Chat "I'm sorry <green><player.name><yellow>. You appear to have insufficient funds for this transaction."
      - Wait 1
      - Chat "Will there be anything else for you today?"
      - ^zap step:Anymore_Else script:Wolfden_Player_Shop

Wolfden_Player_Shop_Shop_Insufficient_Funds_Task:
    type: task
    Requirements:
    Mode: None
    Script:
      - Chat "I'm sorry <green><player.name><yellow>. The shop has insufficient funds for this task."
      - Wait 1
      - Chat "Will there be anything else for you today?"
      - ^zap step:Anymore_Else script:Wolfden_Player_Shop
# END INSUFFICIENT FUNDS TASK
# GREETING TASK IMPORTANT
Wolfden_Player_Shop_Greeting_Task:
    type: Task
    Requirements:
    Mode: None
    Script: 
      - CHAT "Hello there <green><player.name><yellow>, welcome to <aqua><npc.flag[Store_Name]>."
      - CHAT "I am owned by <aqua><npc.owner.name>."
      - CHAT "Simply type <aqua>Inventory<yellow> to see what we offer, and click an item of interest!"
      - ^ZAP step:Non_Owner_Chat script:Wolfden_Player_Shop
##############################################      
Wolfden_Player_Shop_Owner_Task:
    type: Task
    Requirements:
    Mode: None
    Script: 
      - CHAT "Hey there <green>Boss<yellow>!"
      - CHAT "Is there something you need? Just type <aqua>Actions<yellow> to see what I can do."
      - ^ZAP step:2 script:Wolfden_Player_Shop

# INSUFFICIENT ITEM AMOUNT
Wolfden_Player_Shop_No_Item:
    type: task
    Requirements:
    Mode: None
    Script:
      - Chat "I'm sorry <green><player.name><yellow>. But you don't appear to have <aqua><player.flag[wolfden_Player_Shop_purchase_quantity]> <player.flag[wolfden_Player_Shop_purchase_item_colloquial]><yellow>."
      - Chat "Please specify a different number to sell."
      - ^Zap step:Sell_Item_Amount script:Wolfden_Player_Shop

# INSUFFICIENT SHOP ITEM AMOUNT
Wolfden_Player_Shop_Shop_No_Item:
    type: task
    Requirements:
    Mode: None
    Script:
      - Chat "I'm sorry <green><player.name><yellow>. But we don't have <aqua><player.flag[npc_store_purchase_item_selected_quantity]><yellow> of <aqua><player.flag[npc_store_purchase_item_selected]><yellow> in stock."
      - Chat "The Shop currently has <aqua><npc.inventory.qty[<player.flag[npc_store_purchase_item_selected]>]><yellow> of <aqua><player.flag[npc_store_purchase_item_selected]><yellow> in stock."
      - Chat "Please specify a different amount to buy"
      - ^Zap step:Buy_Item_Confirm_Quantity script:Wolfden_Player_Shop